start tok64 d64-Bd2Whi
0 REM "bin-dec-hex",1
10 REM"{delete*7}bin->dec->hex konverter (c) 1990 mr.p.
19 REM"{delete*7}softwolves software 1990/08/04.
24 REM"{delete*7}{-*40}
100 POKE650,128:POKE53280,14:POKE53281,14:PRINT"{yellow}{clear}bin[r till dec till hex konverter{white}
110 PRINT"{down}bin[r? ";:bi$=""
120 PRINT"{reverse on}Z{reverse off}{left}";
130 GETa$:IFa$=CHR$(13)THENPRINT" ":GOTO200
140 IFa$="."ANDp=0THENp=1:GOTO170
150 IFa$=CHR$(20)ANDbi$<>""THENPRINT"{left}{space*2}{left*2}";:GOTO180
160 IFa$<"0"ORa$>"1"THEN130
170 PRINTa$;:bi$=bi$+a$:GOTO120
180 IFRIGHT$(bi$,1)="."THENp=0
190 bi$=LEFT$(bi$,LEN(bi$)-1):GOTO120
200 IFLEFT$(bi$,1)="."THENbi$="0"+bi$
210 IFbi$=""THENPRINT"{down*2}":END
220 FORi=1TOLEN(bi$)
230 IFMID$(bi$,i,1)="."THENbh$=LEFT$(bi$,i-1):bd$=MID$(bi$,i+1):GOTO260
240 NEXT
250 bh$=bi$:bd$="0"
260 s=0:ra=.:FORi=LEN(bh$)TO1STEP-1
270 va=2^ra*VAL(MID$(bh$,i,1))
280 s=s+va:ra=ra+1
290 NEXT
300 ra=-1
310 FORi=1TOLEN(bd$)
320 va=2^ra*VAL(MID$(bd$,i,1))
330 s=s+va:ra=ra-1
340 NEXT
350 IFLEN(bh$)/4<>INT(LEN(bh$)/4)THENbh$="0"+bh$:GOTO350
360 IFLEN(bd$)/4<>INT(LEN(bd$)/4)THENbd$=bd$+"0":GOTO360
370 d$=MID$(STR$(s),2):IFLEFT$(d$,1)="."THENd$="0"+d$
380 PRINT"{up}bin{space*2}= %"bh$"."bd$:PRINT"dec{space*2}= #"d$
390 h$=""
400 FORi=1TOLEN(bh$)STEP4
410 s$=MID$(bh$,i,4):RESTORE
420 READf$,k$:IFf$<>s$THEN420
430 h$=h$+k$:NEXT
440 IFbd$="{0*4}"THEN490
450 h$=h$+".":FORi=1TOLEN(bd$)STEP4
460 s$=MID$(bd$,i,4):RESTORE
470 READf$,k$:IFf$<>s$THEN470
480 h$=h$+k$:NEXT
490 PRINT"hex{space*2}= $"h$
500 RUN110
510 DATA0000,0,0001,1,0010,2,0011,3
520 DATA0100,4,0101,5,0110,6,0111,7
530 DATA1000,8,1001,9,1010,a,1011,b
540 DATA1100,c,1101,d,1110,e,1111,f
stop tok64
(bastext 1.0)